configure.ac

#     -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.69])
AC_INIT([treedec], [0.9.3+], [larisch.larisch@kaust.edu.sa,felix@salfelder.org])
AC_CONFIG_SRCDIR([src/graph_traits.hpp])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([])
LT_INIT()

AM_CONDITIONAL([DIST], [false] )

# debugging
AC_MSG_CHECKING([if debug code should be compiled in])
AC_ARG_ENABLE([debug],
[AS_HELP_STRING([--enable-debug],[Enable building of debug code. [[default: disabled]]])],
[
if test "X$enable_debug" = "Xno" ; then
   AC_MSG_RESULT([no])
else
   AC_MSG_RESULT([yes])
   enable_debug=yes
   enable_develop=yes
fi
],
[
   AC_MSG_RESULT([no])
   enable_debug=no
])

AC_MSG_CHECKING([if develop code should be compiled in])
AC_ARG_ENABLE([develop],
[AS_HELP_STRING([--enable-develop],[Enable building of develop code. [[default: disabled]]])],
[
if test "X$enable_develop" = "Xno" ; then
   AC_MSG_RESULT([no])
else
   AC_MSG_RESULT([yes])
   enable_develop=yes
fi
],
[
   AC_MSG_RESULT([no])
   enable_debug=no
])

# Checks for programs.
AC_PROG_CXX
AC_LANG(C++)
AX_COMPILER_VENDOR

OLD_CXXFLAGS="CXXFLAGS"
CXXFLAGS="$CXXFLAGS"

# python stuff
default_python_version=2.7
AC_ARG_WITH([python],
 [AS_HELP_STRING([--with-python],
	[Enable python library])],
 [python=$withval],
 [python="auto"])

AS_IF([test "$python" = auto], [
  AM_PATH_PYTHON([$default_python_version],
					  [python="$default_python_version"], [python="no"]
					 )
],[
AS_IF([test "$python" != no], [
python_version_required="${python##python}"
AM_PATH_PYTHON([$python_version_required],,
   AC_MSG_ERROR([python $PYTHON_VERSION is not $python_version_required])
	)
])])

AC_ARG_VAR([CYTHON], [the Cython compiler])

AS_IF([test "$python" != no], [

PYTHON_INCLUDE_DIR=$PYTHON_PREFIX/include
PYTHON_LIB_DIR=$PYTHON_PREFIX/lib

AC_ARG_WITH(python-include-dir,
            [  --with-python-include-dir=DIR look in DIR for Python headers],
            [PYTHON_INCLUDE_DIR=$withval],)
AC_SUBST(PYTHON_INCLUDE_DIR)

AC_ARG_WITH(python-lib-dir,
            [  --with-python-lib-dir=DIR look in DIR for Python libraries],
            [PYTHON_LIB_DIR=$withval],)
AC_SUBST(PYTHON_LIB_DIR)
])

AM_CONDITIONAL([USE_PYTHON], [test x$python != xno] )

cythonver_req="0.20.0"

CYTHON=${CYTHON-cython}

AS_IF([test "$python" != no], [
	AC_PATH_PROGS([CYTHON], [$CYTHON], [no])
	AS_IF([test "$CYTHON" = no], [
			 cython=no
			 AC_MSG_RESULT([cannot find cython.])
			 ],
    AC_MSG_CHECKING([for $CYTHON >= $cythonver_req])
    [cythonver=`$CYTHON --version 2>&1 | sed -e 's/[[^0-9\.]]//g'`]
    AS_IF([test -n "$cythonver"], [
      AS_VERSION_COMPARE(${cythonver},${cythonver_req},
	    [cmp=-1],[cmp=0],[cmp=1])
	    AC_MSG_RESULT([${cythonver}])
      AS_IF([test "${cmp}" = "-1"],
	    [AC_MSG_ERROR([need $CYTHON >= $cythonver_req])])
		],[
      AC_MSG_RESULT([not identified])
	 ])
    unset cythonver
	 cython=no
	)
])

AM_CONDITIONAL([USE_CYTHON], [test x$cython != xno] )

# Checks for libraries.

# Checks for header files.

AC_LANG_PUSH([C++])

# unconditional c++11
CXXFLAGS=" $CXXFLAGS"

AC_CHECK_HEADERS([boost/tuple/tuple.hpp], [],
                 AC_MSG_ERROR([could not find a boost header])
)

have_boostlibs=yes
AC_CHECK_LIB([boost_system], [main], , have_boostlibs=no)
AC_CHECK_LIB([boost_thread], [main], , have_boostlibs=no)

have_gala=no

AC_ARG_WITH([gala], AS_HELP_STRING([--without-gala], [Disable gala]))

AS_IF([test "x$with_gala" != xno], [
	AC_CHECK_HEADERS([gala/graph.h],
	                 [ have_gala=yes ],
	                   AC_MSG_NOTICE([consider installing gala])
	)
   AS_IF([test "x$with_gala" = xyes -a x$have_gala = xno], [
									 AC_MSG_ERROR([gala not found, but set])
		 ])
])

AM_CONDITIONAL([USE_GALA], [test $have_gala = yes])

AC_CHECK_HEADERS([tlx/container/btree_set.hpp])
AC_LANG_POP([C++])

# BUG: in auto mode disable python if there are no headers...
AS_IF([test "$python" != no], [
AS_IF([test x"$PYTHON" != x], [
  AM_CHECK_PYTHON_HEADERS([:],
	[AC_MSG_ERROR(please install python headers matching $PYTHON)])
])
])

# HACK. actually we only check if profiling works.
# it doesnt with clang.
AM_CONDITIONAL([CLANG], [test "x$ax_cv_cxx_compiler_vendor" = "xclang"])

# HACK. does old automake not support nested conditionals??
AM_CONDITIONAL([TDECOMP], [test "$have_gala" = yes -a "$have_boostlibs" != no -a "x$ax_cv_cxx_compiler_vendor" != "xclang"])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE

# Checks for library functions.

if test "$enable_develop" = "yes" ; then
	CPPFLAGS="$CPPFLAGS -DTRACE_UNTESTED"
	CXXFLAGS="$CXXFLAGS -Wall -Wextra -pedantic"
fi

if test "$enable_debug" = "yes" ; then
	CXXFLAGS="$CXXFLAGS -O0 -g"
else
	CPPFLAGS="$CPPFLAGS -DNDEBUG"
fi

AM_CONDITIONAL([VPATH_BUILD], [test ! x$srcdir = "x."])

AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([examples/Makefile])
AC_CONFIG_FILES([examples/gr/Makefile])
AC_CONFIG_FILES([tdlib/Makefile])
AC_CONFIG_FILES([tdlib/tests/Makefile])
AC_CONFIG_FILES([treedec/Makefile])
AC_CONFIG_FILES([treedec/tests/Makefile])
AC_CONFIG_FILES([src/Makefile])
AC_CONFIG_FILES([src/bits/Makefile])
AC_CONFIG_FILES([src/applications/Makefile])
AC_CONFIG_FILES([src/impl/Makefile])
AC_CONFIG_FILES([tests/Makefile])

AC_OUTPUT

if test -d .git; then
	:
else
	echo '*' > .gitignore
fi

AC_MSG_RESULT([
** Configuration summary for $PACKAGE $VERSION:

   prefix:     $prefix
   PYTHON:     $PYTHON
   CYTHON:     $CYTHON
   gala:       $have_gala
   CXX:        $CXX
   CPPFLAGS:   $CPPFLAGS
   CXXFLAGS:   $CXXFLAGS
   LIBS:       $LIBS
])