Multiloader!!

.github/workflows/build.yml

@@ -24,7 +24,7 @@ jobs:
         uses: actions/setup-java@v4
         with:
           java-version: ${{ matrix.java }}
-          distribution: 'microsoft'
+          distribution: 'temurin'
       - name: make gradle wrapper executable
         run: chmod +x ./gradlew
       - uses: actions/cache@v4
@@ -36,10 +36,10 @@ jobs:
           restore-keys: |
             ${{ runner.os }}-gradle-
       - name: build
-        run: ./gradlew remapJar
+        run: ./gradlew build
       - name: capture build artifacts
         if: ${{ matrix.java == '21' }} # Only upload artifacts built from latest java
         uses: actions/upload-artifact@v4
         with:
           name: Artifacts
-          path: build/libs/
+          path: build/artifacts/

.gitignore

@@ -38,3 +38,4 @@ hs_err_*.log
 replay_*.log
 *.hprof
 *.jfr
+runs

build.gradle.kts

@@ -0,0 +1,12 @@
+plugins {
+    id("fabric-loom") version "1.8-SNAPSHOT" apply false
+    id("net.neoforged.moddev") version "2.0.88" apply false
+    id("com.gradleup.shadow") version "9.0.0-beta15" apply false
+}
+
+tasks.register("build") {
+    group = "all"
+
+    dependsOn(project(":fabric").tasks.named("build"))
+    dependsOn(project(":neoforge").tasks.named("build"))
+}

buildSrc/build.gradle.kts

@@ -0,0 +1,7 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    mavenCentral()
+}

buildSrc/src/main/kotlin/multiloader-common.gradle.kts

@@ -0,0 +1,103 @@
+plugins {
+    id("java-library")
+    id("maven-publish")
+}
+
+base {
+    archivesName = "${"mod_id"()}-${project.name}-${"minecraft_version"()}"
+}
+
+java {
+    toolchain.languageVersion = JavaLanguageVersion.of("java_version"())
+    withSourcesJar()
+    withJavadocJar()
+}
+
+repositories {
+    mavenCentral()
+
+    maven("https://maven.fabricmc.net/")
+    maven("https://maven.parchmentmc.org/")
+    maven("https://maven.neoforged.net/releases")
+    maven("https://maven.blamejared.com")
+    maven("https://mvn.devos.one/snapshots")
+    maven("https://maven.ladysnake.org/releases")
+    maven("https://maven.terraformersmc.com/")
+    maven("https://maven.nucleoid.xyz")
+    maven("https://maven.alexdevs.me/releases")
+    maven("https://maven.stardustmodding.org/releases")
+}
+
+tasks.named<Jar>("sourcesJar") {
+    from(rootProject.file("LICENSE")) {
+        rename { "${it}_${"mod_id"()}" }
+    }
+}
+
+tasks.named<Jar>("jar") {
+    from(rootProject.file("LICENSE")) {
+        rename { "${it}_${"mod_id"()}" }
+    }
+
+    manifest {
+        attributes(
+            mapOf(
+                "Specification-Title" to "mod_name"(),
+                "Specification-Vendor" to "mod_authors"(),
+                "Specification-Version" to "mod_version"(),
+                "Implementation-Title" to project.name,
+                "Implementation-Version" to "mod_version"(),
+                "Implementation-Vendor" to "mod_authors"(),
+                "Built-On-Minecraft" to "minecraft_version"()
+            )
+        )
+    }
+}
+
+tasks.processResources {
+    var expandProps = mapOf(
+        "mod_version" to "mod_version"(),
+        "mod_group_id" to "mod_group_id"(),
+        "minecraft_version" to "minecraft_version"(),
+        "minecraft_version_range" to "minecraft_version_range"(),
+        "fabric_version" to "fabric_version"(),
+        "fabric_loader_version" to "fabric_loader_version"(),
+        "mod_name" to "mod_name"(),
+        "mod_authors" to "mod_authors"(),
+        "mod_id" to "mod_id"(),
+        "mod_license" to "mod_license"(),
+        "mod_description" to "mod_description"(),
+        "neo_version" to "neo_version"(),
+        "neo_version_range" to "neo_version_range"(),
+        "neo_loader_version_range" to "neo_loader_version_range"(),
+        "mod_credits" to "mod_credits"(),
+        "java_version" to "java_version"()
+    )
+
+    filesMatching(
+        listOf(
+            "pack.mcmeta", "fabric.mod.json", "META-INF/mods.toml", "META-INF/neoforge.mods.toml", "*.mixins.json"
+        )
+    ) {
+        expand(expandProps)
+    }
+
+    inputs.properties(expandProps)
+}
+
+publishing {
+    publications {
+        register<MavenPublication>("mavenJava") {
+            artifactId = base.archivesName.get()
+            from(components["java"])
+        }
+    }
+
+    repositories {
+        maven {
+            mavenLocal()
+        }
+    }
+}
+
+operator fun String.invoke(): String = rootProject.ext[this] as? String ?: error("No property \"$this\"")

buildSrc/src/main/kotlin/multiloader-loader.gradle.kts

@@ -0,0 +1,9 @@
+plugins {
+    id("multiloader-common")
+}
+
+dependencies {
+    compileOnly(project(":common"))
+}
+
+operator fun String.invoke(): String = rootProject.ext[this] as? String ?: error("No property \"$this\"")

common/build.gradle.kts

@@ -0,0 +1,37 @@
+plugins {
+    id("multiloader-common")
+    id("net.neoforged.moddev")
+}
+
+neoForge {
+    neoFormVersion = "neoform_version"()
+
+    val at = file("src/main/resources/META-INF/accesstransformer.cfg")
+
+    if (at.exists()) {
+        accessTransformers.from(at.absolutePath)
+    }
+
+    parchment {
+        minecraftVersion = "parchment_minecraft"()
+        mappingsVersion = "parchment_version"()
+    }
+}
+
+dependencies {
+    compileOnly("org.ow2.asm:asm-tree:9.8")
+    compileOnly("org.spongepowered:mixin:0.8.5")
+    compileOnly("io.github.llamalad7:mixinextras-common:0.3.5")
+    annotationProcessor("io.github.llamalad7:mixinextras-common:0.3.5")
+
+    compileOnly("org.spongepowered:configurate-core:${"configurate_version"()}")
+    compileOnly("org.spongepowered:configurate-hocon:${"configurate_version"()}")
+    compileOnly("org.spongepowered:configurate-gson:${"configurate_version"()}")
+    compileOnly("com.typesafe:config:1.4.3")
+    compileOnly("io.leangen.geantyref:geantyref:1.3.16")
+    compileOnly("eu.pb4:placeholderapi:${"placeholderapi_nf_version"()}")
+    compileOnly("eu.pb4:sgui-neoforge:${"sgui_version"()}")
+    compileOnly("net.luckperms:api:5.4")
+}
+
+operator fun String.invoke(): String = rootProject.ext[this] as? String ?: error("No property \"$this\"")

common/src/main/java/me/alexdevs/solstice/Paths.java

@@ -0,0 +1,9 @@
+package me.alexdevs.solstice;
+
+import me.alexdevs.solstice.api.platform.PlatformHelper;
+
+import java.nio.file.Path;
+
+public class Paths {
+    public static final Path configDirectory = PlatformHelper.get().getConfigDir().resolve(Solstice.MOD_ID);
+}